home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Loadstar 9
/
009.d81
/
in between
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-08-26
|
4KB
|
144 lines
100 gx=53272:uc=21:lc=23:sc=1024:co=55296::of=co-sc
110 bo=53280:bc=53281:sd=54272
120 rempoke ml "quiet" routine
130 forx=50000to50018
140 reada:pokex,a:next
150 data169,0,133,253,169,212,133,254
160 data160,0,152,145,253,200,192,24
170 data208,249,96
180 print"[147] [144]in between":pokegx,uc
190 pokebc,7:pokebo,2:dimc%(52):k$=""
200 pa$=" "
210 e$=""+pa$+pa$+pa$
220 input" how many players 1[157][157][157]";n
230 ifn=0then220
240 ifn=1thenm(1)=100:goto260
250 forx=1ton:input" name of player #";n$(x):m(x)=100:next
260 print"[147] each player begins with $100.00"
270 print" the ante per deal is $5.00"
280 print" aces are always high"
290 print" no doubles":gosub630:gosub1090:kt=0
300 print"":forz=1to9:print" ":next
310 print"":forz=1to9:print" ":next
320 print"":forz=1to9:print" ":next
330 gosub960:ifp>0then380
340 ifn=1thenp=5
350 printe$;"[144]pot's empty!":print"everybody ante up!":gosub 720:printe$
360 forx=1to n:ifm(x)>=5thenp=p+5:m(x)=m(x)-5
370 next
380 kt=kt+1:ifkt>nthenkt=1
390 ifm(kt)<=0then380
400 ifn=1then430
410 printe$:print"";n$(kt);"'s turn"
420 gosub1040:d=500:gosub740
430 m(kt)=m(kt)-5:p=p+5
440 ifcl<6thenprinte$"":gosub630
450 gosub1040
460 gosub670:c1=c%(c):c%(c)=0:cd=1:ca=c1:gosub900:c1=ca:gosub750
470 gosub670:c2=c%(c):c%(c)=0:cd=2:ca=c2:gosub900:c2=ca:gosub750
480 ifabs(c1-c2)>1then510
490 print"tough luck!":gosub 1180:gosub720:print"[145] "
500 printe$:goto610
510 printe$:input"your bet 0[157][157][157]";b$
520 l=len(b$):b$=right$(b$,l-10):b=val(b$)
530 ifb<=0then300
540 ifb>m(kt)orb>pthenprint"too much! ":gosub1180:gosub720
545 ifb>m(kt)orb>pgoto510
550 m(kt)=m(kt)-b:p=p+b
560 gosub670:c3=c%(c):c%(c)=0:cd=3:ca=c3:gosub900:c3=ca:gosub750
570 cw=c1:ch=c2:ifc1>c2thencw=c2:ch=c1
580 ifc3<=cworc3>=chthenprinte$:print"[144]you lose!":gosub1260:goto600
590 printe$:print"[156]a winner!":gosub1360:m(kt)=m(kt)+2*b:p=p-2*b
600 gosub1040:gosub720
610 ifm(kt)<=5thengosub1130
620 printe$:goto300
630 print"shuffling[144]":forx=1to52:c%(x)=0:next:forx=1to52
640 y=int(rnd(1)*52)+1
650 ifc%(y)=0thenc%(y)=x:next:cl=52:printe$:return
660 goto640
670 c=int(rnd(1)*52)+1:ifc%(c)=0then670
680 cl=cl-1:ifc%(c)<14thens=1:return
690 ifc%(c)<27thens=2:return
700 ifc%(c)<40thens=3:return
710 s=4:return
720 d=800
730 remdelay subroutine
740 forde=1tod:nextde:return
750 sp$="":vt$="":br$="":bl$=""
760 ifcd=2thensp$=""
770 ifcd=3thenvt$=vt$+"":sp$="":br$="[165]":bl$="[157][167]"
780 s$=mid$("[211][218][193][216]",s,1):su$="[156]":ifs>2thensu$="[144]"
790 n1$=str$(ca):l=len(n1$)
800 ifl=2thenn$=right$(n1$,1)+" "
810 ifca=10thenn$="10":n1$=n$
820 ifca=11thenn$="j ":n1$=" j"
830 ifca=12thenn$="q ":n1$=" q"
840 ifca=13thenn$="k ":n1$=" k"
850 ifca=14thenn$="a ":n1$=" a"
860 ifcd=3thenprint"[144][164][164][164]"
870 printvt$;sp$;su$;bl$;n$;" ";s$;br$:bl$=""
880 forx=1to2:printsp$;" ":next:printsp$;" ";s$;" "
890 forx=1to2:printsp$;" ":next:printsp$;s$;" ";n1$:print"[144]":return
900 ifca<14then940
910 ifca<27thenca=ca-13:goto940
920 ifca<40thenca=ca-26:goto940
930 ca=ca-39
940 ifca=1thenca=14
950 return
960 ifn=1andm(n)<=5thenprint"[147][156]sorry! you're out!":goto1150
970 ifn=1thenreturn
980 j=0:forh=1ton
990 ifm(h)>5thenj=j+1:w1=h
1000 next
1010 ifj>1thenreturn
1020 pokebo,8:pokebc,4:print"[147][144]";n$(w1);"[146] is the":print"winner with $";
1030 r=1:kt=w1:gosub1040:printm$:goto1150
1040 m=m(kt):m1=m-int(m):m$=str$(m1)+"00":m$=str$(int(m))+"."+mid$(m$,2,2)
1050 ifr=1thenreturn
1060 p1=p-int(p):p$=str$(p1)+"00":p$=str$(int(p))+"."+mid$(p$,2,2)
1070 print""k$"you have":printk$" ":printk$"[145]$"m$
1080 printk$"pot: ":printk$" ":printk$"[145]$"p$"":return
1090 pokebc,5:pokebo,5:print"[147]";:forz=1to23:printpa$:nextz
1100 forz=sc+39tosc+999step40:pokez,160:pokez+of,5:nextz
1110 forz=sc+859tosc+999:pokez,160:pokez+of,5:nextz
1120 pokebo,5:pokebc,1:return
1130 ifn=1thenreturn
1140 printe$:print"[144]you're out of it,":print""n$(kt):gosub720:return
1150 d=4500:gosub720:input"play again y[157][157][157]";a$
1160 ifa$="y"thenrun
1170 print"[147]":goto63000
1180 remhonk!
1190 sys50000:remcall silence routine
1200 poke54296,15:poke54277,64
1210 poke54278,128:poke54273,11
1220 poke54272,210:poke54276,17
1230 d=250:gosub740
1240 poke54276,16
1250 sys50000:return
1260 remdown sound
1270 sys50000
1280 pokesd+24,15:pokesd+5,192
1290 pokesd+6,250
1300 forxx=240to20step-5
1310 pokesd+1,xx
1320 pokesd+4,17
1330 next
1340 sys50000
1350 return
1360 rem winsound
1370 sys50000
1380 pokesd+24,15:pokesd+5,192
1390 pokesd+6,250
1400 forxx=1to10
1410 pokesd+1,100
1420 pokesd+4,17
1430 d=30:gosub740
1440 pokesd+1,150
1450 pokesd+4,17
1460 next
1470 sys50000
1480 return
63000 rem connect back to l.s.
63002 print"[147]load"chr$(34)"c.payload"chr$(34)",8":print"run"
63004 poke198,0:poke631,13:poke632,13:poke198,2:end